Where Are All the Monet Paintings?

I’ve been curious to know, which museums have the most paintings by Claude Monet (or my other favorite artists)? For instance, when I travel, which museums should I go to? Which cities or countries should I include in my trip if I want to see the most art I’ll enjoy? Or, if I’m already in a city/country, are there any museums I should go to based on my tastes?

When I search the web for answers, I’m dissatisfied. I find the couple of museums with the largest quantity of Monet paintings (e.g. Musée Marmatton Monet and Musée d’Orsay) and the best museums to go to if you’re in a destination country (e.g. France or the United States) or city (e.g. Paris or New York) but it doesn’t help beyond that. For example, would I be more satisfied with a trip to the Philadelphia Museum of Art or the Museum of Fine Arts Boston? Are there any museums with a large collection that I haven’t heard of before?

I discovered the information I need is on Wikidata, accessible with a SPARQL query. You can make queries using the Wikidata Query Service (WQS) web interface. Use the mouse to hover over terms like wd:Q296 to see its label and description (in this case, wd:Q296 is Claude Monet’s identifier). Let’s look at a few different queries below.

Query #1: collections with the most paintings by Monet

This is the query I created (link to edit/execute query directly in WQS):

SELECT
  (COUNT(DISTINCT ?painting) AS ?paintingCount)
  ?collectionLabel
  ?collectionCountryLabel
WHERE {
  ?painting wdt:P170 wd:Q296;           # creator = Monet
    wdt:P31 wd:Q3305213;                # instanceOf = painting
    (wdt:P195/(wdt:P361*)) ?collection. # partOf a collection
  OPTIONAL { ?collection wdt:P17 ?collectionCountry. } # get collection country
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en".
  }
}
GROUP BY ?collection ?collectionLabel ?collectionCountryLabel
ORDER BY DESC (?paintingCount)

And here are the top ten results, downloaded as an HTML table from WQS and repasted here:

What did we learn?

• Paris has significantly more Monet paintings than New York: 179 vs. 43 works in the top ten collections. This difference isn’t as clear in web search results.
• I’d probably be more satisfied with the 38 works in the Museum of Fine Arts Boston over the 22 works at the Philadelphia Museum of Art. Surprising to me, that’s a few more works than at the Art Institute of Chicago which is known for its Impressionism collection.
• I’ve never heard of the Museum Barberini in Germany but it seems like it’d be a good stop if I’m in the area.

Now, this list isn’t perfect. For example, “Impressionism: The Hasso Plattner Collection” is located at the Museum Barberini but both are listed here: perhaps if I was more knowledgeable about Wikidata’s data representation and SPARQL I could eliminate that. Furthermore, the data set isn’t perfect: at the time of writing, Museum Barberini lists 40 paintings by Monet on their website but this query returns 38. However, this dataset is good enough for me to get an idea of where Monet’s paintings are.

If you use this as a guide of which museums to visit, remember that not all of these paintings may be “on view” right now: they may be in storage, on loan, etc. Check the collection search of the official museum website to find out what’s being displayed.

Query #2: countries with the most paintings by Monet

(Link to edit/execute query directly in WQS)

SELECT
  (COUNT(DISTINCT ?painting) AS ?paintingCount)
  ?collectionCountryLabel
WHERE {
  ?painting wdt:P170 wd:Q296;           # creator = Monet
    wdt:P31 wd:Q3305213;                # instanceOf = painting
    (wdt:P195/(wdt:P361*)) ?collection. # partOf a collection
  OPTIONAL { ?collection wdt:P17 ?collectionCountry. } # get collection country
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en".
  }
}
GROUP BY ?collectionCountryLabel
ORDER BY DESC (?paintingCount)

These are the countries I should focus on if I want to see Monet paintings (the blank field probably indicates paintings in private collections). Curiously, the United States has more paintings than France even though above we learned that Paris has more paintings than New York: it seems like France’s Monet collection may be more densely located than the United States’ collection.

Data notes

While these queries worked well for Monet, the data quality between artists can be varied. For example, a less well-known painter like American Edgar Payne has only 6 paintings entered in Wikidata (despite Wikimedia Commons having 133 images of his paintings). In this case, Wikimedia contributors have uploaded many images but have not entered their metadata into Wikidata.

Different fields have varying quality too: there are 997 Monet paintings without the Impressionism movement property even though many of them look Impressionist to me. This data quality issue would make finding the museums with the largest number of Impressionist paintings difficult.

The Wikimedia resources also have many images of Monet paintings. If you want to see them, you have a few options:

• Add images to your Wikidata query, e.g. Monet paintings in the Metropolitan Museum of Art
• Find a list on Wikipedia, e.g. List of Paintings by Claude Monet
• Search Wikimedia Commons (example), find an associated Gallery page there (e.g. Paintings by Claude Monet), or find a Category (e.g. Paintings by Claude Monet in the Metropolitan Museum of Art). Note that you won’t easily find all of his paintings in a single category because images can only be in one category and categories can have subcategories.

Much of Wikidata’s data is licensed under CC0 which, as I understand it and I am not a lawyer, means it is dedicated to the public domain: see Wikidata:Copyright for more information.

I’m impressed with Wikidata’s collection of painting information: it’s like an IMDB or Goodreads but for paintings. In fact, the “sum of all paintings” WikiProject has a goal to have a Wikidata item for every notable painting. I’m curious what else I can find out in Wikidata.

The data provided by Wikidata, in tables, is licensed under CC0: see Wikidata:Copyright for more information. The remainder of Where are all the Monet Paintings? by Michael Comella is licensed under Creative Commons Attribution-ShareAlike 4.0 International